Loops
Loops provide a way to repeat certain operations multiple times. Consider this function:
module main
# This func prints: 1 2 3 4 5 6 7 8 9 10 done
func start()
console::init()
console::print_int(1)
console::print(" ")
console::print_int(2)
console::print(" ")
console::print_int(3)
console::print(" ")
console::print_int(4)
console::print(" ")
console::print_int(5)
console::print(" ")
console::print_int(6)
console::print(" ")
console::print_int(7)
console::print(" ")
console::print_int(8)
console::print(" ")
console::print_int(9)
console::print(" ")
console::print_int(10)
console::print(" ")
console::print("done")
end func
end module
Instead of duplicating the code multiple times, we can make a variable i which counts upwards.
module main
# This func prints: 1 2 3 4 5 6 7 8 9 10 11 12...
func start()
var i: int
0 -> i
console::init()
loop
i + 1 -> i
console::print_int(i)
console::print(" ")
end loop
end func
end module
The code between loop and end loop will repeat endlessly. Each time through this loop, i + 1 -> i will increase the value of i by one. This prints the numbers 1 through 10, but then it keeps counting forever. How to end the loop?
Drop
The drop statement is used to exit a loop. (The drop keyword is often called break in other programming languages.) It moves control to the next statement after end loop. Here is how to use drop to stop counting when we reach 10:
module main
# This func prints: 1 2 3 4 5 6 7 8 9 10 done
func start()
var i: int
0 -> i
console::init()
loop
i + 1 -> i
# Stop when we reach 10
if i > 10 then
drop
end if
console::print_int(i)
console::print(" ")
end loop
console::print("done")
end func
end module
Lift
The lift statement causes control to move immediately to the top of the loop. (The lift keyword is often called continue in other programming languages.) In other words, it skips the rest of the loop. We can use lift to skip the even numbers:
module main
# This func prints: 1 3 5 7 9 done
func start()
var i: int
0 -> i
console::init()
loop
i + 1 -> i
# Skip the even numbers
if i % 2 = 0 then
lift
end if
# Stop when we reach 10
if i > 10 then
drop
end if
console::print_int(i)
console::print(" ")
end loop
console::print("done")
end func
end module
Relationship to JUMP
If you look at the Chombit assembly language that the compiler produces, you will see that loop is implemented using JUMP instructions. Normally programs go step by step, executing one statement after another. A jump causes the CPU to move to an arbitrary step, instead of the next one.
We can understand loop in terms of jumps:
. . .
loop
# 🎯 Position A
i + 1 -> i
if i % 2 = 0 then
# 👆 Jump up to position A
lift
end if
# Stop when we reach 10
if i > 10 then
# 👇 Jump down to position B
drop
end if
console::print_int(i)
console::print(" ")
# 👆 Jump up to position A
end loop
# 🎯 Position B
console::print("done")
. . .
Some programming languages allow arbitrary jumps, for example using goto statement. This is much more flexible, however it turns out that jumps are very difficult to understand and debug. Code is much easier to understand if we restrict ourselves to use only loop, lift, drop, and if for jumping around. In practice, this restriction does not limit the kinds of programs that we can write.
Nesting loops
You can put loop inside another loop. For example, suppose a chess board has 8 rows and 8 columns. To clear every square, we might use an outer loop to count through the rows, and an inner loop to count through the columns.
Here is a simple example of two loops:
module main
# This func will print:
#
# 1 2 3 4 5
# 1 2 3 4
# 1 2 3
# 1 2
# 1
func start()
var i: int, top: int
console::init()
5 -> top
loop
# 🎯 Position C
1 -> i
loop
# 🎯 Position D
console::print_int(i)
console::print(" ")
i + 1 -> i
if i > top
do drop # 👇 Jump down to position E
# 👆 Jump up to position D
end loop
# 🎯 Position E
console::print("{n}") # new line
top - 1 -> top
if top <= 0
do drop # 👇 Jump down to position F
# 👆 Jump up to position C
end loop
# 🎯 position F
end func
end module
Numbered loops
What if we wanted to drop out of two nested loops? For example, suppose we're trying to find an empty square on a chessboard. An outer loop counts through the rows of the board, and the inner loop counts through the columns. When we find an empty cell, then we exit both loops.
To support this, Hybrix allows you to label your loop with numbers, and then drop and lift can refer to those numbers. In the example below, the outer loop is number 100 and the inner loop is number 200. This allows drop 100 to exit both loops:
module main
# Returns the chess piece at the given row and column
# or 0 if the square is empty.
func get_cell(col: int, row: int): int
# TODO: Put some code here
end func
func start()
var row: int, col: int
# Find the first empty square
0 -> row
loop 100
# 🎯 Position G
0 -> col
loop 200
# 🎯 Position H
if main::get_cell(col, row) = 0
do drop 100 # 👇 Jump down to position J
col + 1 -> col
if col >= 8
do drop 200 # 👇 Jump down to position I
# 👆 Jump up to position H
end loop 200
# 🎯 Position I
row + 1 -> row
if row >= 8
do kernel::fail("board is full")
# 👆 Jump up to position G
end loop 100
# 🎯 Position J
# TODO: Put a chess piece at (col, row)
end func
end module
Note:
loop 100does NOT mean loop 100 times. The number 100 is just a label for the loop. Its numeric value is unimportant.
The number label for loop is only required if a lift statement refers to it. And the number label for end loop is only required if a drop statement refers to it. Thus, the above example can be written more concisely as:
module main
# Returns the chess piece at the given row and column
# or 0 if the square is empty.
func get_cell(col: int, row: int): int
# TODO: Put some code here
end func
func start()
var row: int, col: int
# Find the first empty square
0 -> row
loop
0 -> col
loop
if main::get_cell(col, row) = 0
do drop 100
col + 1 -> col
if col >= 8
do drop
end loop
row + 1 -> row
if row >= 8
do kernel::fail("board is full")
end loop 100
# TODO: Put a chess piece at (col, row)
end func
end module